Пример инвентаря (кликабельный)

Скачать архив тестового проекта.

init -2 python:
    items = [] # пустой список
    last_item = None # пустой последний нажатый пункт
    # регистрируем канал для списка,
    # чтобы он не выключал звуки из игры:
    renpy.music.register_channel("itms", "sfx", False)
    # здесь может быть любой обработчик нажатия кнопки из списка
    def SelectItemF(index):
        # сюда ставить код обработчика на питоне
        # например, удалим пункт из списка и запомним его значение
        if (index >= 0) and (index < len(items)):
            last_item = items.pop(index)
            # а если не хотим удалять нажатый пункт:
            # last_item = items[index]
            # теперь добавим звук нажатия на пункт списка:
            renpy.play("sounds/buy.mp3", channel="itms")
            # а это чтобы перерисовать/обновить экраны:
            renpy.restart_interaction()
    # превращаем функцию в action
    SelectItem = renpy.curry(SelectItemF)
    # получить имя файла
    def GetFN(index=0):
        global items
        if (index >= 0) and (index < len(items)):
            fn, hn = items[index]
            return "inventory/" + fn + ".png"
        else:
            return ""
    # получить подсказку
    def GetHint(index=0):
        global items
        if (index >= 0) and (index < len(items)):
            fn, hn = items[index]
            return hn
        else:
            return ""

init:
    image bg world1 = "bg_world1.png"
    image mario = "mario.png"
    $ invent = False

screen inventory:
    zorder 111
    default tt = Tooltip(" ")
    frame:
        xalign 1.0
        background Solid("#0000")
        xmaximum 130
        ymaximum 450
        xfill True
        vbox:
            imagebutton auto "inventory/bag_%s.png" action SetVariable("invent", not invent)
            if invent:
                text tt.value
                hbox:
                    viewport id "box":
                        yinitial 9999
                        xmaximum 0.9
                        mousewheel True
                        draggable True
                        vbox:
                            for i in range(0, len(items)):
                                imagebutton:
                                    idle Image(GetFN(i))
                                    hover Image(GetFN(i))
                                    hovered tt.Action(GetHint(i))
                                    # действие при нажатии на пункт:
                                    action SelectItem(i)
                    vbar yfill True value YScrollValue("box")

label start:
    scene black
    # начальные значения для списка
    $ last_item = None
    $ items = [("coin", "Денюжка"), ("flower", "Цветочег"), ("goomba", "Гумба")]
    # экран со списком:
    show screen inventory
    scene bg world1
    show mario
    with dissolve
    "Нажми на чемоданчик. Затем жми на экран."
    # добавление пунктов в список:
    $ items.extend([("mushroom", "Грыбок"), ("plant", "Сорняк"), ("star", "Пёздочка")])
    "В инвентарь добавлено три предмета."
    return

    # чтобы узнать из любого места последний нажатый пункт:
    # if last_item != None:
        # fn, hn = last_item
        # в fn будет имя файла картинки,
        # в hn - имя пункта, подсказка
        # после чего переменную по желанию можно обнулить
        # last_item = None