Вставка видео-спрайта. Переключаем каналы

Ссылка на архив с проектом

init python:
    # окно игры в центре экрана
    import os
    os.environ['SDL_VIDEO_CENTERED'] = '1'
    # автоматическое объявление изображений
    config.automatic_images_minimum_components = 1
    config.automatic_images = [' ', '_', '/']
    config.automatic_images_strip = ['images']

    # названия всех видео
    tvchan_name = ["sitcom", "comedy", "sport"]

    # объявление всех спрайтов с видео
    for i in tvchan_name:
        renpy.image("tv " + i, Movie(play= i + ".mp4", pos=(444, 44), anchor=(0, 0), size=(320, 240)))

# Игра начинается здесь.
label start:
    scene bg tvset
    $ tvchan = ""

label chan_select:
    # выбор канала
    menu:
        "Что будем смотреть?"
        "Сериал":
            $ tvchan = "sitcom"
        "Камеди":
            $ tvchan = "comedy"
        "Спорт":
            $ tvchan = "sport"
        "Ничего":
            $ tvchan = ""
            hide tv

    # если канал выбран, то запускаем соответствующее видео
    if tvchan:
        show expression "tv " + tvchan as tv
        pause
        jump chan_select

    # если канал не выбран
    "Займусь лучше делом."
    return